【9RIA—ladeng6666】—【Box2D系列教程 31】让Box2D刚体无阻尼匀速运动

9RIA-ladeng6666

转载：9RIA游戏开发者社区（天地会）
作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/


【Box2D系列教程-导航帖】—拉登大叔出品（总贴）



Box2D物理引擎默认情况下，对世界b2World里的刚体都是模拟自由落体运动，并且因为摩擦力的影响，刚体会慢慢的停下来(在物理学上也叫做有阻尼运动)。今天我们来学习一下，让刚体不受摩擦力影响，无阻尼匀速运动下去。

首先我们要消除重力，让刚体不做自由落体运动。我们曾在Box2D自定义重力中，学习了如何消除重力。因为本节示例中的所有刚体都不受重力影响，所以直接在创建的b2World对象时，直接设置重力为零向量new b2Vec2(0,0)就可以了。

[Actionscript3] 纯文本查看 复制代码

//创建重力为0的Box2D世界
world = world = new b2World(new b2Vec2(0,0), true);

现在刚体可以老老实实的停在舞台上了，接下来我们要让它动起来。让刚体动起来，就是要让它有速度，可以通过b2Body的SetLinearVelocity()方法设置刚体的运动速度。这个用一个b2Vec2向量作为参数，这个向量包含了刚体速度的方向和大小。

[Actionscript3] 纯文本查看 复制代码

//设置刚体的速度
body.SetLinearVelocity(velocity);

现在问题也来了，刚体运动起来后，由于摩擦力的作用，速度会渐渐慢下来。你可以修改Box2D的源代码，取消摩擦力模拟，不过这是一个相当复杂的工作，因为一般人是很难弄懂Box2D里的底层算法的，也没有这必要。另外一个方法就是实时调整刚体的速度大小，注意这里指的的是大小，不包括方向，我们还是希望Box2D能帮忙的准确的完成反弹的。

调整向量的大小而不影响它的速度，可以将向量单位化，然后用Multiply()方法设置它的长度，Multiply()的参数即为要设置的向量长度。代码如下：

[Actionscript3] 纯文本查看 复制代码

//单位化刚体速度，只保留速度的方向
velocity.Normalize();
//设置刚体速度的大小为speed，因为是在ENTER_FRAME事件处理器里实时更新
//所以我们看不到刚体速度的减慢
velocity.Multiply(speed);

下面的示例中，有5个圆形不停的在Box2D中无阻尼匀速运动。


完整的代码和注释如下：

[Actionscript3] 纯文本查看 复制代码

package  
{
        import Box2D.Common.Math.b2Vec2;
        import Box2D.Dynamics.b2Body;
        import Box2D.Dynamics.b2World;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;

        /**
         * ...
         * @author ladeng6666
         */
        public class Main extends Sprite 
        {
                private var world:b2World;

                //刚体运动的速度
                private var speed:Number = 7;

                public function Main() 
                {
                        createWorld();//创建世界
                        createBodies();//创建刚体
                        //添加事件侦听器
                        addEventListener(Event.ENTER_FRAME, loop);
                }
                //创建Box2D世界
                private function createWorld():void 
                {
                        //创建重力为0的Box2D世界
                        world = world = new b2World(new b2Vec2(0,0), true);
                        addChild(LDEasyBox2D.createDebug(world));
                        LDEasyBox2D.stage = stage;
                        LDEasyBox2D.createWrapWall(world, this);
                }

                private function createBodies():void 
                {
                        var body:b2Body;
                        var velocity:b2Vec2;
                        var angle:Number;

                        for (var i:int = 0; i < 5; i++) {
                                body = LDEasyBox2D.createCircle(world, Math.random()*400+100, Math.random()*300+50, 30);
                                //设置随机的速度方法
                                angle = Math.random() * Math.PI * 2;
                                //速度的大小统一都是speed
                                velocity = new b2Vec2(speed * Math.sin(angle), speed * Math.cos(angle));
                                //设置刚体的速度
                                body.SetLinearVelocity(velocity);
                        }

                }

                private function loop(e:Event):void 
                {
                        var body:b2Body = world.GetBodyList();
                        var velocity:b2Vec2;
                        //遍历所有的刚体，设置它们的速度大小
                        for (; body; body = body.GetNext()) {
                                        velocity = body.GetLinearVelocity();
                                        //单位化刚体速度，只保留速度的方向
                                        velocity.Normalize();
                                        //设置刚体速度的大小为speed，因为是在ENTER_FRAME事件处理器里实时更新
                                        //所以我们看不到刚体速度的减慢
                                        velocity.Multiply(speed);
                        }
                        LDEasyBox2D.updateWorld(world);
                }

        }

}

下载：
2012-11-11 让Box2D刚体无阻尼匀速运动.rar (344.21 KB, 下载次数: 0)

2018-2-6 12:26 上传

点击文件名下载附件