【9RIA—ladeng6666】—【Box2D系列教程 32】用b2WorldManifold获取Box2D刚体碰撞点

9RIA-ladeng6666

转载：9RIA游戏开发者社区（天地会）
作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/


【Box2D系列教程-导航帖】—拉登大叔出品（总贴）


时候游戏中发生碰撞时，我们希望在碰撞位置添加一个爆炸效果，这就要知道碰撞点的位置。Box2D中发生碰撞时，都会生成一个b2Contact对象，包含了大量的碰撞信息，其中就包括了我们今天学习的b2WorldManifold获取碰撞点信息。

b2Contact中有两个获取Manifold的方法，一个是GetManifold()，获取相对于刚体的碰撞点本地坐标(具体请参考这里)；另一个是GetWorldManifold()，获取相对于舞台的碰撞点全局坐标。因为我们要在碰撞点位置添加效果，这个效果的坐标是相对于舞台的全局坐标，所以用到GetWorldManifold()方法。

在下面的效果中，我沿用了让Box2D刚体无阻尼匀速运动中的示例，当碰撞发生时，通过GetWorldManifold方法在碰撞位置添加一个红色的圆圈(当然你也可以换成其他的效果，如爆炸动画)。



完整的代码和注释如下：

[Actionscript3] 纯文本查看 复制代码

package  
{
        import Box2D.Collision.b2WorldManifold;
        import Box2D.Common.Math.b2Vec2;
        import Box2D.Dynamics.b2Body;
        import Box2D.Dynamics.b2World;
        import Box2D.Dynamics.Contacts.b2Contact;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;

        /**
         * ...
         * @author ladeng6666
         */
        public class Main extends Sprite 
        {
                private var world:b2World;

                //刚体运动的速度
                private var speed:Number = 2;
                //声明碰撞点
                private var contactPoint:b2Vec2;
                private var contactListener:MyContactListener;

                public function Main() 
                {
                        createWorld();//创建世界
                        createBodies();//创建刚体
                        //添加事件侦听器
                        addEventListener(Event.ENTER_FRAME, loop);
                }
                //创建Box2D世界
                private function createWorld():void 
                {
                        //创建重力为0的Box2D世界
                        world = world = new b2World(new b2Vec2(0,0), true);
                        addChild(LDEasyBox2D.createDebug(world));
                        LDEasyBox2D.stage = stage;
                        LDEasyBox2D.createWrapWall(world, this);

                        //设置碰撞侦听函数
                        contactListener = new MyContactListener();
                        world.SetContactListener(contactListener);
                }

                private function createBodies():void 
                {
                        var body:b2Body;
                        var velocity:b2Vec2;
                        var angle:Number;

                        for (var i:int = 0; i < 5; i++) {
                                body = LDEasyBox2D.createCircle(world, Math.random()*400+100, Math.random()*300+50, 30);
                                body.beginContactHanlder = contactHanlder;
                                //设置随机的速度方法
                                angle = Math.random() * Math.PI * 2;
                                //速度的大小统一都是speed
                                velocity = new b2Vec2(speed * Math.sin(angle), speed * Math.cos(angle));
                                //设置刚体的速度
                                body.SetLinearVelocity(velocity);
                        }

                }

                private function contactHanlder(self:b2Body,bodyB:b2Body):void 
                {
                        //获取contact对象
                        var contact:b2Contact = contactListener.myContact;
                        //定义一个b2WorldManifold对象，用来获取并存储碰撞点的全局坐标
                        var manifold:b2WorldManifold = new b2WorldManifold();
                        //通过GetWorldManifolde方法，计算出碰撞点的全局坐标，并存储到manifold变量中
                        contact.GetWorldManifold(manifold);
                        //获取碰撞点
                        contactPoint = manifold.m_points[0];
                        //在碰撞点位置添加一个红色的圆圈
                        addChild(new CircleShape(contactPoint.x * 30, contactPoint.y * 30));
                }

                private function loop(e:Event):void 
                {
                        var body:b2Body = world.GetBodyList();
                        var velocity:b2Vec2;
                        //遍历所有的刚体，设置它们的速度大小
                        for (; body; body = body.GetNext()) {
                                        velocity = body.GetLinearVelocity();
                                        //单位化刚体速度，只保留速度的方向
                                        velocity.Normalize();
                                        //设置刚体速度的大小为speed，因为是在ENTER_FRAME事件处理器里实时更新
                                        //所以我们看不到刚体速度的减慢
                                        velocity.Multiply(speed);
                        }
                        LDEasyBox2D.updateWorld(world);
                }

        }

}

代码的重点是66到78行，其他的代码和让Box2D刚体无阻尼匀速运动中的差不多。

第71行：创建一个b2WorldManifold对象，稍后传递给GetWorldManifold()方法，用来计算和存储碰撞点的全局坐标。

第73行：调用b2Contact.GetWorldManifold()方法，在这个方法中实例化b2WorldManifold对象，并计算出bodyA和bodyB碰撞的位置，存储到b2WorldManifold.m_points属性中，m_points是一个Vector数组，最多会有2个元素，这取决于刚体碰撞的类型。不过通常我只用m_points[0]就足够了。

第75行：获取碰撞点坐标。

第77行：将坐标点单位转换为像素，在这个位置添加一个红色的圆圈。CircleShape类中除了绘制红色圆圈外，还有一个Timer对象，用来淡出圆圈，具体详见源代码。



下载：
2012-11-23 获取碰撞检测位置.rar (344.4 KB, 下载次数: 0)

2018-2-6 13:07 上传

点击文件名下载附件