【9RIA—ladeng6666】—【Box2D系列教程 23】谁动了我的刚体——Box2D碰撞检测

9RIA-ladeng6666

转载：9RIA游戏开发者社区（天地会）
作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/


【Box2D系列教程-导航帖】—拉登大叔出品（总贴）



今天我们来学习用Box2D的b2Contact和b2ContactListener来获取碰撞对象(Box2D中用contact一词来表示碰撞，知道这一点，对后面的理解会有帮助）。

Box2D是一个非常强大的2D物理引擎，可以帮我们实现精确的碰撞检测，并模拟2D碰撞。但有时候只知道"碰撞了"是不够了，就像我在"谈谈碰撞检测"里讲到的，针对不同的游戏，碰撞后的处理方式是不同的，可能是变更运动轨迹(如桌球游戏)、可能是销毁对象(如愤怒的小鸟)等等。而实现这一切可能的效果，首先要先知道碰撞的对象，所以就有了今天的教程。

Box2D中获取碰撞对象的方法有两种。一个是通过world.GetContactList().bodyA和bodyB来获取碰撞双方；另外一个是自定义Box2D.Dynamics下的b2ContactListener类，侦听碰撞后的事件，然后做进一步的处理。下面我们来看看具体的实现方法。

一、用world.GetContactList()方法获取碰撞对象
world.GetContactList()会返回一个b2Contact对象。前面我说过的，Box2D中contact是碰撞的意思，所以可以猜想到，b2Contact肯定跟碰撞有关。是的，b2Contact用来管理碰撞的shape，任何有超过两个及以上接触点的刚体，Box2D都认为发生了碰撞，并用b2Contact来管理。

通过b2Contact的GetFixtureA()和GetFixtureB()方法，我们可以获取碰撞对象的b2Fixture属性引用，进而获取碰撞对象。具体代码举例如下：

[Actionscript3] 纯文本查看 复制代码

var contactList:b2Contact = world.GetContactList();
var bodyA:b2Body = contactList.GetFixtureA().GetBody();
var bodyB:b2Body = contactList.GetFixtureB().GetBody();

二、用b2ContactListener获取碰撞对象
从b2ContactListener的名字上大家应该可以猜到，它是Box2D对象碰撞检测侦听器，当刚体之间发生碰撞时，Box2D引擎会自动调用这个类的相关方法，然后做进一步的处理。这些方法包括：
    BeginContact：当碰撞发生时触发该方法
    EndContact：当碰撞结束时触发该方法

使用b2ContactListener的方法有两种。
一、修改b2ContactListener的BeginContact和EndContact方法，添加碰撞处理代码；
二、继承b2ContactListener类，如自定义一个myContactListener子类，然后重写子类的BeginContact和EndContact方法，然后将子类传递给world.world.SetContactListener()方法，自定义碰撞侦听器。

[Actionscript3] 纯文本查看 复制代码

package
{
        import Box2D.Common.Math.b2Vec2;
        import Box2D.Dynamics.b2ContactListener;
        import Box2D.Dynamics.Contacts.b2Contact;

        /**
         * ...
         * @author ladeng6666
         */
        public class MyContactListener extends b2ContactListener
        {

                public function MyContactListener()
                {
                        super();
                }
                override public function BeginContact(contact:b2Contact):void
                {
                        //碰撞后给碰撞对象添加向上的冲力
                        contact.GetFixtureA().GetBody().ApplyImpulse(new b2Vec2(0, -10));
                        contact.GetFixtureB().GetBody().ApplyImpulse(new b2Vec2(0, -10));
                }
                override public function EndContact(contact:b2Contact):void
                {
                        //同样可以和BeginContact方法一样，定义一些碰撞处理方式
                }

        }

}

三、如何使用Box2D的碰撞对象
在Flash中编写碰撞检测代码时，通常我们会用A对象(如游戏主角)的hitTest或hitTestObject方法检查它与另外一个对象的碰撞，当碰撞发生时，分别对A和B进行碰撞处理。这里我们很清楚哪个是A对象(游戏主角)，那个是B对象(敌人)。

但是在b2Contact或b2ContactListener中，我们获取的bodyA和bodyB无法知道哪个是游戏主角，哪个是敌人，分不出个青红皂白，所以只能一棒子打死啦。我的意思是，比如我现在想找到碰撞的对象是否是游戏主角，那么就得分别确认一下bodyA和bodyB了，游戏碰撞对象种类越多，判断越复杂。具体在下面的实例中，我会在代码注释里解释。

在下面的示例中，有一个静态的矩形对象，屏幕顶部会不断的掉下圆形和矩形刚体，当发生碰撞后，圆形刚体会向左运动，矩形会向右运动。



完整的代码和注释如下：

[Actionscript3] 纯文本查看 复制代码

package
{
        import Box2D.Dynamics.Contacts.b2Contact;
        import flash.display.MovieClip;
        import flash.events.MouseEvent;

        import Box2D.Common.Math.b2Vec2;
        import Box2D.Dynamics.b2Body;
        import Box2D.Dynamics.b2World;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.KeyboardEvent;
        import flash.ui.Keyboard;

        /**
         * [url]http://www.ladeng6666.com[/url]
         * @author ladeng6666
         */
        public class Main extends Sprite
        {
                //创建世界的基本元素
                private var world:b2World;
                private var debugSprite:Sprite;

                private var contactList:b2Contact;

                private var age:Number = 30;
                private var interval:Number = 0;

                public function Main()
                {
                        //创建一个world世界
                        LDEasyBox2D.stage = this;
                        world=LDEasyBox2D.createWorld();
                        debugSprite=LDEasyBox2D.createDebug(world);
                        addChild(debugSprite);

                        //创建刚体数据，通过个对象的.name属性，可以判断对象的类型，是矩形？是圆形？还是静态地面
                        var bd:BodyData = new BodyData();
                        bd.name = "ground";
                        //创建矩形刚体
                        LDEasyBox2D.createBox(world, stage.stageWidth / 2, 300, 400,20, true,bd);

                        //侦听事件
                        addEventListener(Event.ENTER_FRAME, loop);
                }
                private function createBodies():void {
                        //没30帧随机创建一个刚体，可能是圆形刚体，也可能是矩形刚体
                        if (++interval > age) {
                                var bd:BodyData = new BodyData();
                                if (Math.random() > 0.5) {
                                        //通过BodyData对象定义刚体的类型，在碰撞检测时，我们会通过这个属性判断刚体的类型
                                        bd.name = "rect";
                                        LDEasyBox2D.createBox(world, Math.random() * 300 + 100, 0, 40, 30, false, bd);
                                }else {
                                        //通过BodyData对象定义刚体的类型，在碰撞检测时，我们会通过这个属性判断刚体的类型
                                        bd.name = "circle";
                                        LDEasyBox2D.createCircle(world, Math.random() * 300 + 100, 0, 20, false, bd);
                                }
                                interval = 0;
                        }
                }
                private function loop(e:Event):void
                {
                        //更新世界
                        LDEasyBox2D.updateWorld(world);
                        //创建刚体
                        createBodies();
                        //获取world的b2Contact对象
                        contactList = world.GetContactList();
                        if (contactList != null) {
                                //如果发生了碰撞，记录碰撞的双方bodyA和bodyB
                                var bodyA:b2Body = contactList.GetFixtureA().GetBody();
                                var bodyB:b2Body = contactList.GetFixtureB().GetBody();

                                /**
                                 * 碰撞的双方有3种可能：
                                 * 1.动态刚体与静态地面碰撞
                                 * 2.动态刚体与动态刚体碰撞
                                 *
                                 * 我们需要处理的动态刚体与静态地面碰撞，并移动动态刚体，但是我们不知道哪个是静态地面
                                 * 所以只能分别对bodyA和bodyB进行判断
                                 */
                                //判断bodyA是不是静态地面
                                if (bodyA.GetUserData().name == "ground") {
                                        //如果是静态地面，然后根据bodyB的类型，进行不同的处理
                                        if (bodyB.GetUserData().name == "rect") {
                                                bodyB.ApplyImpulse(new b2Vec2(1*bodyB.GetMass()), bodyB.GetWorldCenter());
                                        }else {
                                                bodyB.ApplyImpulse(new b2Vec2(-1*bodyB.GetMass()), bodyB.GetWorldCenter());
                                        }
                                //判断bodyA是不是静态地面
                                //试着删除elseif里面的内容，看看不同的结果(矩形刚体将不会向右移动)
                                }else if (bodyB.GetUserData().name == "ground") {
                                        //判断bodyA是不是静态地面
                                        if (bodyA.GetUserData().name == "rect") {
                                                bodyA.ApplyImpulse(new b2Vec2(1*bodyA.GetMass()), bodyA.GetWorldCenter());
                                        }else {
                                                bodyA.ApplyImpulse(new b2Vec2(-1*bodyA.GetMass()), bodyA.GetWorldCenter());
                                        }
                                }
                        }
                        //清除超出屏幕的刚体
                        var body:b2Body = world.GetBodyList();
                        for (; body; body = body.GetNext()) {
                                if (body.GetPosition().y > 400/30) {
                                        world.DestroyBody(body);
                                }
                        }

                }

        }

}
//自定义一个用户数据类
import flash.display.Sprite;

class BodyData extends flash.display.Sprite{

}

下载：
OK 2012-06-30 谁动了我的刚体.rar (341.94 KB, 下载次数: 2)

2018-2-6 11:45 上传

点击文件名下载附件